≥ Greater than or equal

Compares each element in the left-hand argument with the corresponding element in the right-hand argument. If an element in the left-hand argument is greater than, or equal to, the corresponding right-hand element, the result of that comparison is 1. Otherwise it is 0. (This operation is affected by ⎕CT, the comparison tolerance)

             12 ≥ 1
       1
             2 ≥ 12
       0
             12 ≥ 12
       1
             11 7 2 5 ≥ 11 3 2 6     (Compares each element in a vector with
       1 1 1 0                        the corresponding element in a vector of
                                      equal length)
             ¯3≥¯4                   (Compares negative numbers. The number
       1                              nearer 0 is considered the greater.)
             8 ≥ 2+2+2+2             (The right argument is evaluated
       1                              before the comparison is made)
             TABLE ← 2 3 ⍴ 1 2 3 4 5 6
             MABLE ← 2 3 ⍴ 3 3 3 5 5 5
             TABLE ≥ MABLE           (Compares each element in a matrix
       0 0 1                          with the corresponding element in
       0 1 1                          a matrix of equal size and dimensions)
             3≥TABLE
       1 1 1
       0 0 0
             3 ≥ TABLE MABLE         (Compares 3 with the elements of the
        1 1 1  1 1 1                  nested vector)
        0 0 0  0 0 0