≢ Not Match

The Not Match function ≢ will test whether its arguments are different in any respect - depth, rank, shape or corresponding elements. The result is always a scalar 1 or 0. It is equivalent to ~L ≡ R

             3≢3                     (Two scalars are identical)
       0
             3≢,3                    (Scalar does not match a vector)
       1
             4 7.1 8 ≢ 4 7.2 8       (Shape is the same but values are not)
       1
             (3 4⍴⍳12)≢3 4⍴⍳12       (Two matrices are identical)
       0
             (3 4 ⍴⍳12)≢⊂3 4⍴⍳12     (Simple matrix does not match an enclosed
       1                              version of itself)
             VEC←'ABC' 'DEF'         (Two element vector of 'ABC' 'DEF)
             VEC
       ABC DEF
             ⍴VEC                    (Length 2)
       2
             VEC≢'ABCDEF'            (Does not match the 6 element vector
       1                              'ABCDEF')

The comparisons done by this operation are affected by ⎕CT, the comparison tolerance value.

See ≡ Match for more information on how the comparisons are done.